plc4good.org.ua

CONT_C (FB41) Siemens

Siemens (CONT_C)
- .

.

:
english - download .pdf 0.3
- .pdf 0.3

pid

FUNCTION_BLOCK FB41
TITLE =" PID "
AUTHOR : SIMATIC
FAMILY : ICONT
NAME : CONT_C
VERSION : " 1.5"
//reversed by komatic
VAR_INPUT
COM_RST : BOOL ; //
MAN_ON : BOOL := TRUE; //
PVPER_ON : BOOL ; //
P_SEL : BOOL := TRUE; //
I_SEL : BOOL := TRUE; //
INT_HOLD : BOOL ; //
I_ITL_ON : BOOL ; //
D_SEL : BOOL ; //
CYCLE : TIME := T#1S; //
SP_INT : REAL ; //
PV_IN : REAL ; //
PV_PER : WORD ; // ()
MAN : REAL ; //
GAIN : REAL := 2.000000e+000; //
TI : TIME := T#20S; //
TD : TIME := T#10S; //
TM_LAG : TIME := T#2S; //
DEADB_W : REAL ; //
LMN_HLM : REAL := 1.000000e+002; //
LMN_LLM : REAL ; //
PV_FAC : REAL := 1.000000e+000; // ()
PV_OFF : REAL ; // ()
LMN_FAC : REAL := 1.000000e+000; // ()
LMN_OFF : REAL ; // ()
I_ITLVAL : REAL ; //
DISV : REAL ; //
END_VAR
VAR_OUTPUT
LMN : REAL ; //
LMN_PER : WORD ; // ()
QLMN_HLM : BOOL ; //
QLMN_LLM : BOOL ; //
LMN_P : REAL ; //
LMN_I : REAL ; //
LMN_D : REAL ; //
PV : REAL ; //
ER : REAL ; //
END_VAR
VAR
sInvAlt : REAL ;
sIanteilAlt : REAL ;
sRestInt : REAL ;
sRestDif : REAL ;
sRueck : REAL ;
sLmn : REAL ;
sbArwHLmOn : BOOL ; //
sbArwLLmOn : BOOL ; //
sbILimOn : BOOL := TRUE;
END_VAR
VAR_TEMP
Hvar : REAL ; //Hilfsvariable
rCycle : REAL ; //Abtastzeit in real
Diff : REAL ; //nderungswert
Istwert : REAL ; //Istwert
ErKp : REAL ; //
rTi : REAL ; //Integrationszeit in real
rTd : REAL ; //Differentiationszeit in real
rTmLag : REAL ; //Verzgerungszeit in real
Panteil : REAL ; //P-Anteil
Ianteil : REAL ; //I-Anteil
Danteil : REAL ; //D-Anteil
Verstaerk : REAL ; //Verstrkung
RueckDiff : REAL ; //Differenz des Rckkopplungswertes
RueckAlt : REAL ; //Alter Rckkopplungswert
dLmn : REAL ; //Stellwert
gf : REAL ; //Hilfwert
rVal : REAL ; //Real Hilfsvariable
END_VAR
BEGIN
IF COM_RST //
THEN
//
sIanteilAlt:=I_ITLVAL;
LMN:=0.0; //
QLMN_HLM:=0; //
QLMN_LLM:=0; //
LMN_P:=0.0; //
LMN_I:=0.0; //
LMN_D:=0.0; //
LMN_PER:=0; // ()
PV:=0.0; //
ER:=0.0; //
sInvAlt:=0.0;
sRestInt:=0.0;
sRestDif:=0.0;
sRueck:=0.0;
sLmn:=0.0;
sbArwHLmOn:=0;
sbArwLLmOn:=0;
ELSE
rCycle:= DINT_TO_REAL(TIME_TO_DINT(CYCLE)) / 1000.0; //
Istwert:=INT_TO_REAL(WORD_TO_INT(PV_PER)) * 100.0 / 27648.0; // (0-2768 0-100)
Istwert:=Istwert * PV_FAC + PV_OFF; //
IF NOT PVPER_ON THEN Istwert:=PV_IN; END_IF; // PV_IN
PV:= Istwert; //
ErKp:=SP_INT - PV; //
IF ErKp < (-DEADB_W) THEN ER:=ErKp+DEADB_W; //
ELSIF ErKp > DEADB_W THEN ER:=ErKp-DEADB_W; // .
ELSE ER:=0.0; // .
END_IF;
ErKp:=ER * GAIN; // ,
rTi:=DINT_TO_REAL(TIME_TO_DINT(TI)) / 1000.0; //
rTd:=DINT_TO_REAL(TIME_TO_DINT(TD)) / 1000.0; //
rTmLag:=DINT_TO_REAL(TIME_TO_DINT(TM_LAG)) / 1000.0; // .
//
IF rTi < (rCycle * 0.5) THEN rTi:=rCycle * 0.5; END_IF; // - Cycle / 2
IF rTd < rCycle THEN rTd:=rCycle; END_IF; // - Cycle
IF rTmLag < rCycle * 0.5 THEN rTmLag:=rCycle * 0.5; END_IF; // ..- Cycle / 2
//
IF P_SEL
THEN
Panteil:=ErKp; //
ELSE
Panteil:=0.0;
END_IF;
//---------------------------------------------------------------------------------------------
//
//---------------------------------------------------------------------------------------------
IF I_SEL //
THEN
IF I_ITL_ON //
THEN
Ianteil:=I_ITLVAL;
sRestInt:=0.0;
ELSE
IF MAN_ON //
THEN
Ianteil:=sLmn - Panteil - DISV;
sRestInt:=0.0;
ELSE //
Diff:=rCycle / rTi *(ErKp + sInvAlt) * 0.5 + sRestInt;
IF ((Diff>0.0) AND sbArwHLmOn OR INT_HOLD)OR ((Diff<0.0) AND sbArwLLmOn) THEN Diff:=0.0; END_IF;
Ianteil:=sIanteilAlt + Diff;
sRestInt:=sIanteilAlt - Ianteil + Diff;
END_IF;
END_IF;
ELSE
Ianteil:=0.0;
sRestInt:=0.0;
END_IF;
//---------------------------------------------------------------------------------------------
//
//---------------------------------------------------------------------------------------------
Diff:=ErKp;
IF (NOT MAN_ON) AND D_SEL
THEN
Verstaerk:= rTd / (rCycle * 0.5 + rTmLag);
Danteil:= (Diff - sRueck) * Verstaerk;
RueckAlt:= sRueck;
RueckDiff:= rCycle / rTd * Danteil + sRestDif;
sRueck:= RueckDiff + RueckAlt;
sRestDif:=RueckAlt - sRueck + RueckDiff;
ELSE
Danteil:=0.0;
sRestDif:=0.0;
sRueck:=Diff;
END_IF;
//---------------------------------------------------------------------------------------------
//
//---------------------------------------------------------------------------------------------
dLmn:=Panteil + Ianteil + Danteil + DISV;
IF MAN_ON //
THEN
dLmn:=MAN; //
ELSE
IF (NOT I_ITL_ON) AND I_SEL
THEN
IF (Ianteil > (LMN_HLM - DISV)) AND (dLmn > LMN_HLM) AND ((dLmn - LMN_D)> LMN_HLM)
THEN
rVal:=LMN_HLM - DISV;
gf:= dLmn - LMN_HLM;
rVal:=Ianteil - rVal;
IF rVal > gf THEN rVal:=gf; END_IF;
Ianteil:=Ianteil - rVal;
ELSE
IF (Ianteil < (LMN_LLM - DISV)) AND (dLmn < LMN_LLM) AND ((dLmn - LMN_D) < LMN_LLM)
THEN
rVal:=LMN_LLM - DISV;
gf:=dLmn - LMN_LLM;
rVal:=Ianteil - rVal;
IF rVal < gf THEN rVal:=gf; END_IF;
Ianteil:=Ianteil - rVal;
END_IF;
END_IF;
END_IF;
END_IF;
LMN_P:=Panteil;
LMN_I:=Ianteil;
LMN_D:=Danteil;
sInvAlt:=ErKp;
sIanteilAlt:=Ianteil;
sbArwHLmOn:=0;
sbArwLLmOn:=0;
IF (dLmn >= LMN_HLM)
THEN
QLMN_HLM:=1;
QLMN_LLM:=0;
dLmn:=LMN_HLM;
sbArwHLmOn:=1;
ELSE
QLMN_HLM:=0;
IF (dLmn <= LMN_LLM)
THEN
QLMN_LLM:=1;
dLmn:=LMN_LLM;
sbArwLLmOn:=1;
ELSE
QLMN_LLM:=0;
END_IF;
END_IF;
sLmn:=dLmn;
dLmn:=sLmn * LMN_FAC + LMN_OFF;
LMN:=dLmn;
dLmn:=LMN * 2.764800e+002;
IF dLmn >= 3.251100e+004
THEN
dLmn:=3.251100e+004;
ELSE
IF dLmn <= -3.251200e+004
THEN
dLmn:=-3.251200e+004;
END_IF;
END_IF;
LMN_PER:= INT_TO_WORD(REAL_TO_INT(dLmn));
END_IF;
END_FUNCTION_BLOCK